randomize:cls

dim s$(1),l(26),k(26,4),t(3):restore
for i=1 to 26:read l(i):next
for i=1 to 26:for j=1 to l(i)
read k(i,j):next::next

v=40:t(1)=49:t(2)=54:t(3)=62:ton=2

5 box 2,1,7,10,1:print @81,"Speed:";v
print @121,"Tone:";ton:box 2,32,7,40,1
print @113,"Morse":print @153,"V 1.0"
print @193,"LTSH":print @234,"1992"

i=menu(2,11,4,0,0,5,"Menu","Transmit-computer","Transmit-input","Set up","Help")
if i=-1 then cls:end
if i=0 then 10
if i=1 then 40
if i=2 then 70
if i=3 then 90

10 cls:box 1,1,8,40,1:locate 1,12
y=2:ym=y:print " Transmit-computer "
15 scrsave s$(0):beep:x=3
a=menu(ym,20,4,0,0,3,"Are you ready?","Yes","Quit")
if a=-1 or a=1 then cls:goto 5
scrload s$(0):i=0:m$="":locate y,x
repeat:i=i+1
j=int(rnd*25):a$=chr$(j+65):m$=m$+a$
until i=36
gosub 100:print m$:y=y+1:if y<8 then 20
errwin 4,18,"Press any key ...":cls:goto 5
20 ym=ym+1:if ym=6 then ym=1
goto 15

40 cls:box 1,1,8,40,1:print @16," Input "
x=3:y=2:locate y,x
41 m$=""
42 a$=inkey$:if a$="" then 42
if asc(a$)=13 then 45
if a$="*" then 46
a$=ucase$(a$)
if asc(a$)<65 or asc(a$)>90 then 42
locate y,x:print a$;
m$=m$+a$:x=x+1
if x=39 then x=3:y=y+1
if y=8 then gosub 100:cls:goto 5
goto 42
45 gosub 100:goto 41
46 cls:goto 5

70 i=menu(3,12,4,0,0,3,"Set up","Speed","Tone")
if i=-1 then 5 
if i=0 then 73
if i=1 then 76

73 scrsave s$(0):box 4,12,6,22,1:print @133," Speed "
print @172," (1-9):  ":locate 5,20
74 i$=inkey$:if asc(i$)=27 then scrload s$(0):goto 70
i=val(i$)
if i>0 and i<=9 then v=i*10 else 74
print @87,v:goto 5

76 scrsave s$(0):box 4,12,6,21,1:print @133," Tone "
print @173,"(1-3)";
78 i$=inkey$:if asc(i$)=27 then scrload s$(0):goto 70
i=val(i$)
if i>0 and i<4 then ton=i else 78
print @126,i:goto 5

90 cls:box 1,1,8,40,1:locate 1,17,0:print " Help "
print "ºEsc - exit from menus"
print "º*   - exit from 'Transmit-input'"
print @161,"Don't use the programm ALTR.COM!"
print @262,"Press any key ..."
wait
print @41,"This programm can be copied freely."
print @81,"If you like this programm, send me"
print @121,"10DM ($5,”S50,...) and I send you"
print @161,"new version and other programms."
print @201,"Adr: TOMECEK Lad. ml.,Dobrotice 138,"
print @241,"769 01 HOLESOV, CSFR" 
wait:cls:locate 0,0,2:goto 5

100 print@36," ";chr$(14);" ":locate y,x
for i=1 to len(m$)
j=asc(mid$(m$,i,1))-64
for m=1 to l(j):lt=int(380/v*k(j,m))
sound t(ton),lt
next:for p=1 to 4000/v:next:next
print @36,"ÍÍÍ":locate y,x
return

110 data 2,4,4,3,1,4,3,4,2,4,3,4,2,2,3,4
111 data 4,3,3,1,3,4,3,4,4,4

165 data 1,3
166 data 3,1,1,1
167 data 3,1,3,1
168 data 3,1,1
169 data 1
170 data 1,1,3,1
171 data 3,3,1
172 data 1,1,1,1
173 data 1,1
174 data 1,3,3,3
175 data 3,1,3
176 data 1,3,1,1
177 data 3,3
178 data 3,1
179 data 3,3,3
180 data 1,3,3,1
181 data 3,3,1,3
182 data 1,3,1
183 data 1,1,1
184 data 3
185 data 1,1,3
186 data 1,1,1,3
187 data 1,3,3
188 data 3,1,1,3
189 data 3,1,3,3
190 data 3,3,1,1