5  RANDOMIZE:SSIZE=40:DIM D$(40):DIM S$(100)
6  F$="WORDS.DAT"
7  G$="PREP.DAT"
10 CLS:PRINT
15 PRINT "  ************************************"
16 PRINT "  *       PORTFOLIO MASTER WORD      *"
17 PRINT "  *      a simple teaching tool      *"
18 PRINT "  *  (c) - copyrighted as shareware  *"
19 PRINT "  *  Author:  Jan Sedl k, Prague, CZ *"
20 PRINT "  ************************************"
21 PRINT "              hit any key",,
22 IF INKEY$="" THEN 22
25 CLS:PRINT
26 PRINT "   ÉÍ Select your option Í»"
27 PRINT "   º S - Start program    º"
28 PRINT "   º C - Change setting   º"
31 PRINT "   º H - Help about...    º"
32 PRINT "   ÈÍÍÍÍÍ ESC to exit ÍÍÍͼ",,
33 A$=INKEY$
34 IF A$="" THEN GOTO 33
35 IF A$="s" OR A$="S" THEN GOTO 100
36 if asc(A$)=27 THEN GOTO 1100
37 IF A$="c" OR A$="C" THEN GOTO 200
38 IF A$="h" OR A$="H" THEN GOTO 400
40 GOTO 33
100 I=1:A$="":PRINT:PRINT "Working °";
101 OPEN "I",#1,"prep.dat"
102 IF EOF(1) THEN D$(I)=A$:GOTO 120
103 L$=INPUT$(1,#1)
104 IF ASC(L$)=10 THEN GOTO 110
105 IF ASC(L$)<32 THEN GOTO 102
106 A$=A$+L$
107 GOTO 102
110 D$(I)=A$
111 IF I=40 THEN GOTO 120
112 I=I+1:A$="": PRINT "°";
113 GOTO 102
120 D=I
121 CLOSE#1
131 A$="":I=0:f=4:Print@248,"²";
132 OPEN "i",2,f$
133 IF EOF(2) THEN 145
134 L$=INPUT$(1,#2)
135 IF ASC(L$)=10 THEN 140
136 IF ASC(L$)<32 THEN 133
137 A$=A$+L$:if len(a$)>38 then goto 140
138 GOTO 133
140 IF I=100 THEN 145
141 I=I+1:S$(I)=A$:A$=""
142 IF INT(I/2)=I/2 THEN PRINT "²";
143 GOTO 133
145 CLOSE#2
146 F=I:N=1+INT(RND*I)
150 CLS
151 PRINT 
152 PRINT " ÉÍ Here is one phrase for you, but ÍÍ»"
153 PRINT " º something is missing. Fill it in!  º"
154 PRINT " º                                    º"
155 PRINT " º                                    º"
156 PRINT @200," ÈÍÍÍÍÍÍÍÍÍ enter X to exit ÍÍÍÍÍÍÍÍÍͼ"
160 I=1:S$=UCASE$(S$(N))
161 J=INSTR(S$," "+UCASE$(D$(I))+" ")
162 IF J=0 THEN I=I+1:GOTO 161
163 PRINT @124,"                                  ":PRINT @124, LEFT$(S$,J-1);
164 PRINT " *****"; RIGHT$(S$,LEN(S$)-J-LEN(D$(I)));: PRINT @164,"Your tip:                        ";
165 PRINT @175,""; : INPUT A$:IF A$="X" OR A$="x" THEN GOTO 1000
166 IF UCASE$(A$)=UCASE$(D$(I)) THEN 180
167 PRINT @164,"Try again -                       ";:PRINT @200," ÈÍÍÍÍÍÍÍÍÍ second  attempt ÍÍÍÍÍÍÍÍÍͼ";:PRINT @174,"";:INPUT A$
168 IF UCASE$(A$)=UCASE$(D$(I)) THEN 180
169 PRINT @164,"Here it is:                       "; :PRINT @175,S$;:
170 PRINT @200," ÈÍÍÍÍÍÍÍÍÍ   hit any key   ÍÍÍÍÍÍÍÍÍͼ" : N=1+INT(RND*F):WAIT
171 GOTO 156
180 PRINT @124,"                                  "
181 PRINT @124,S$
182 PRINT @164,"       YOU'RE GOOD AT IT          ":PRINT @200," ÈÍÍÍÍÍÍÍÍÍ   hit any key   ÍÍÍÍÍÍÍÍÍͼ"
183 N=1+INT(RND*F):WAIT:GOTO 156
200 cls
PRINT "ÉÍÍ  You can change the source files ÍÍ»"
PRINT "º input the name of a file containing  º"
PRINT "º the phrases:                         º"
PRINT "º FILE:                                º"
print "ÈÍÍÍÍÍÍÍÍÍÍ enter  your choice ÍÍÍÍÍÍÍͼ"
print @130,"";: input a$
if exists(a$) then f$=a$:goto 25
print @130,"";a$;" doesn't exist! "
print "ÈÍÍÍÍÍ hit any key to get to Menu ÍÍÍÍͼ"
wait:goto 25
400 cls 
PRINT " ÉÍÍÍÍÍÍÍÍ  About this program ÍÍÍÍÍÍÍ»"
PRINT " º    a simple program to test your   º"
PRINT " º  prepositions and English phrases  º"
PRINT " º It uses BJ Gleason's PBasic v 4.91 º"
print " ÈÍÍÍÍ hit any key to get to Menu ÍÍÍͼ"
wait:goto 25
1000 cls:
PRINT " É  You're about to leave the program »"
PRINT " º Y - Yes, quit to DOS               º"
PRINT " º M - back to intro Menu             º"
PRINT " º G - play this Game again           º"
print " ÈÍÍÍÍÍÍÍÍ enter  your choice ÍÍÍÍÍÍÍͼ"
1006 a$=inkey$
if a$="Y" or a$="y" then goto 1100
if a$="M" or a$="m" then goto 25
if a$="G" or a$="g" then goto 150
goto 1006
1100 cls
Print "Thank you for running this program."
Print "You can  contact the author at this"
Print "address:"
Print "           Jan Sedlak"
Print "           Sarajevska 29"
Print "           120 00 Praha 2"
Print "           the Czech Republic"
Print "or by phone"
Print "           +42-2-6911163":print
Print " E-mail  sedlakj@dec59.ruk.cuni.cz"
Print "  There are many new things for"
Print "         Atari Portfolio"
Print "        January 8th, 1995"
Print:Print:System