rem f�r Portfolio von R.Rumrich
5 DIM T(49)
10 CLS:PRINT "*****************TAXMAN****************"
15 PRINT
20 INPUT "Gib eine Zahl ein, kleiner als 50";N:IF N<1 OR N>49 THEN 10
30 FOR J=1 TO N
40 T(J) = J
50 NEXT J
60 CLS:V=0:X=0:Y=0:S=0
70 U=39:FOR J = 1 TO N 
80 IF T(J)=0 THEN 95
90 V=V+1:PRINT USING "%3.0f"; J;
95 IF V*3=U THEN V=0:PRINT" "; 
100 NEXT J:U=0:V=0
110 PRINT:INPUT "W�hle eine Zahl ";L
120 IF L<0 OR L>N OR T(L)=0 THEN CLS:GOTO 70
130 Z=0
140 FOR J=1 TO L/2
150 IF T(J)=0 THEN 190
160 IF L<>J*INT(L/J) THEN 190
170 Z=Z+J
180 T(J)=0
190 NEXT J
200 IF Z>0 THEN 230
210 CLS:PRINT "Faktoren ausgortiert, w�hlen Sie neu "
220 GOTO 70
230 T(L)=0
240 X=X+L
250 Y=Y+Z:CLS
260 PRINT "Ich habe  "Y", du hast "X" Punkte"
270 FOR J=2 TO N
280 IF T(J)=0 THEN 340
290 FOR K=1 TO J/2
300 IF T(K)=0 THEN 330
310 IF J<> K*INT(J/K)THEN 330
320 K=J/2: S=1
330 NEXT K:IF S=1 THEN J=N
340 NEXT J:IF S=1 THEN S=0:GOTO 70
350 FOR J=1 TO N
360 IF T(J) =0 THEN 380
370 Y=Y+J
380 NEXT J
390 CLS:PRINT "!! Ende !!! Es gibt keine Faktoren mehr"
400 PRINT "Stand: Du hast "X", ich habe "Y" Punkte"
405 PRINT
410 IF X<Y THEN 425
420 PRINT "**** Bravo **** Du hast gewonnen ****"
421 PRINT:GOTO 450
425 PRINT "**** Leider **** Du hast verloren ****"
430 PRINT:GOTO 450
450 INPUT"Willst du weiterspielen ? (J/N)    ";A$
460 IF A$="J" OR A$="j" THEN 10 ELSE END